home *** CD-ROM | disk | FTP | other *** search
/ TPUG - Toronto PET Users Group / TPUG Users Group CD / TPUG Users Group CD.iso / TPUG Xtras / Xtras / club1.d64 / fast s_tiny dir3 (.txt) < prev    next >
Commodore BASIC  |  2009-02-07  |  4KB  |  102 lines
  1. 0 REM *******************************
  2. 1 REM * TINY DIRECTORY BY R.B.WOLFF *
  3. 2 REM *  PRINTS A TINY 2, 3, OR 5   *
  4. 3 REM *     COLUMN DIRECTORY        *
  5. 4 REM * FX80 PRINTER WITH CARD?/G+  *
  6. 5 REM * 3 & 5 COLUMN AND SUPER SMALL*
  7. 6 REM * OPTIONS BY:FRED  LAYBERGER  *
  8. 7 REM *  OMAHA,NE * NOVEMBER 1984   *
  9. 8 REM * FASTER DIRECTORY READ JAN 85*
  10. 9 REM *  IMPROVED DIR READ MARCH 85 *
  11. 10 REM*******************************
  12. 12 CLR:GOSUB160:GOTO20
  13. 14 REM ...SOUND...
  14. 16 POKE54296,5:POKE54277,2:POKE54278,251:POKE54276,17:POKE54273,80:POKE54272,10
  15. 18 FORI=.TO22:NEXT:FORI=.TO30:POKE54276,16:NEXT:RETURN
  16. 20 DIMN$(145):OPEN15,8,15:ESC$=CHR$(27)
  17. 22 POKE53280,1:POKE53281,15
  18. 24 PRINT"[147]FAST SUPER TINY DIR3[146]"
  19. 25 PRINT"[162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162][162]"
  20. 26 PRINT"PRINTS A TINY 2,3 OR 5":PRINT"COLUMN DIRECTORY"
  21. 28 PRINT"F1-READ/PRINT DIRECTORY"
  22. 30 PRINT"INSERT DISKETTE FIRST"
  23. 32 PRINT"F3-SET/RESET PRINT OPTIONS"
  24. 34 PRINT"F5-QUIT/EXIT TO BASIC"
  25. 36 GOSUB14:IFB>14THENB=.
  26. 38 POKE646,B:PRINT"SELECT ONE":IFA$="[135]"THENCLOSE15:PRINT"[147][144]":END
  27. 40 GETA$:IFA$<>"[133]"ANDA$<>"[134]"THENB=B+1:PRINT"[145][145][145][145][145][145]";:GOTO36
  28. 42 IFA$="[134]"THENGOSUB120:GOTO22
  29. 44 PRINT "[147]WORKING[144]"
  30. 46 POKE850,32:POKE851,228:POKE852,255:POKE952,29
  31. 48 PRINT#15,"I":OPEN1,8,.,"$0":CLOSE1:GOSUB166:OPEN1,8,.,"$0"
  32. 50 SYSDL:N$(.)=MID$(X$,6,22):POKE850,76:POKE851,100:POKE852,3:POKE952,24:CT=1
  33. 52 SYSDL:B$=LEFT$(X$,1):C$=MID$(X$,2,1):T$=STR$(ASC(C$)*256+ASC(B$))
  34. 54 T$=RIGHT$("   "+T$,3):N$(CT)=MID$(X$,2,21)+T$+"  "
  35. 56 PRINT"     "N$(CT):IFST=.THENCT=CT+1:GOTO52
  36. 58 B$=RIGHT$(N$(CT),5)+" BLOCKS FREE ":N$(CT)=""
  37. 60 PRINT"[145]        BLOCKS FREE      "
  38. 62 CLOSE1:GOSUB166:GOSUB118
  39. 64 GOSUB140:CT=CT-1:X=INT(CT/VAL(CS$)):P2=2*X:P3=3*X:P4=4*X
  40. 66 IFLEN(STR$(CT/VAL(CS$)))<=LEN(STR$(CT))THEN90
  41. 68 X=X+1:IFCS$="2"THENP2=2*X-1:GOTO90
  42. 70 IFCS$="5"THEN80
  43. 72 REM  ******* 3 COLUMN *********
  44. 74 IFRIGHT$(STR$(CT/3),1)="3"THENP2=X:P3=2*X-1:GOTO90
  45. 76 IFRIGHT$(STR$(CT/3),1)="4"THENP2=X:P3=2*X-1:GOTO90
  46. 78 P2=2*X:P3=3*X-1:GOTO90
  47. 80 REM  ******* 5 COLUMN *********
  48. 82 IFRIGHT$(STR$(CT/5),1)="2"THENP2=2*X-1:P3=3*X-2:P4=4*X-3:GOTO90
  49. 84 IFRIGHT$(STR$(CT/5),1)="4"THENP2=2*X:P3=3*X-1:P4=4*X-2:GOTO90
  50. 86 IFRIGHT$(STR$(CT/5),1)="6"THENP2=2*X:P3=3*X:P4=4*X-1:GOTO90
  51. 88 P2=2*X:P3=3*X:P4=4*X
  52. 90 REM ******* PRINT TO PRINTER *******
  53. 92 IFPS$<>"R"THENPRINT#4,CHR$(27)"S"CHR$(1);
  54. 94 FORP=1TOX
  55. 96 PRINT#4,N$(P)" ";
  56. 98 IFP2=>P+XTHENPRINT#4,N$(P+X)" ";
  57. 100 IFP+P2>CTTHENPRINT#4:GOTO112
  58. 102 IFP3=>P+P2THENPRINT#4,N$(P+P2)" ";
  59. 104 IFP+P3>CTTHENPRINT#4:GOTO112
  60. 106 IFP4=>P+P3THENPRINT#4,N$(P+P3)" ";
  61. 108 IFP+P4>CTTHENPRINT#4:GOTO112
  62. 110 IFP4+X=>P+P4THENPRINT#4,N$(P+P4)
  63. 112 NEXTP
  64. 114 PRINT#4,ESC$CHR$(64):REM RESET PRINTER
  65. 116 CLOSE4:GOTO22
  66. 118 IFXX=1THENRETURN: :REM                       ******* PRINTER SETUP *********
  67. 120 PRINT"[147]PRINT SELECTION??":PRINT"[144]R[146]EGULAR":PRINT"C[146]ONDENSED"
  68. 122 GOSUB14:PRINT"S[146]UPER CONDENSED":POKE198,0
  69. 124 GETPS$:IFPS$<>"R"THENIFPS$<>"C"THENIFPS$<>"S"THEN124
  70. 126 PRINT"HOW MANY COLUMNS  2[146] OR 3[146]?";:IFPS$="S"THENPRINT"[157][157][157][157][157][157], 3[146] OR 5[146]?"
  71. 128 GOSUB14:POKE198,0
  72. 130 GETCS$:IFCS$<>"2"THENIFCS$<>"3"THENIFCS$<>"5"THEN130
  73. 132 GOSUB14:POKE631,34:POKE198,1:PRINT"[147][144]INPUT TODAYS DATE";:INPUTD$
  74. 134 GOSUB14:INPUT"IS THE PRINTER READY[146][144] (Y[146]/N[146])  Y[157][157][157]";A$
  75. 136 IFA$<>"Y"THENPRINT"[145][145]";:GOTO132
  76. 138 XX=1:PRINT"[147]WORKING...":RETURN
  77. 140 CLOSE4:OPEN4,4,4:PRINT#4,ESC$CHR$(64)ESC$"G";
  78. 142 IFPS$="R"ANDCS$="3"THENPRINT#4,ESC$"E";:GOTO146
  79. 144 PRINT#4,CHR$(15)
  80. 146 PRINT#4,N$(.)" ";:IFPS$="S"ANDCS$="2"THENPRINT#4,CHR$(13);
  81. 148 PRINT#4," "B$D$:PRINT#4,ESC$;CHR$(64);:REM RESET
  82. 150 IFPS$<>"S"THENPRINT#4,ESC$"E";:REM EMPHASIZED
  83. 152 PRINT#4,ESC$CHR$(85)CHR$(0);:REM BIDIRECTIONAL ESC U 0
  84. 154 IFPS$="S"THENPRINT#4,CHR$(15);:REM CONDENSED PRINT
  85. 156 IFPS$<>"R"THENPRINT#4,ESC$CHR$(65)CHR$(6);: REM LN FEED TO 6/72"(1/12")ESCA
  86. 158 RETURN
  87. 160 X$="XX":FORI=.TO3:X$=X$+X$:NEXT
  88. 162 DL=830:RESTORE:FORI=DL TO DL+148:READX:POKEI,X:NEXT
  89. 164 RETURN
  90. 166 POKE198,0:INPUT#15,ER,ER$,T,S:IFER=.THENRETURN
  91. 168 PRINT"[147]"ER;ER$;T;S:WAIT198,1:RUN
  92. 170 DATA160,2,177,45,153,249,0,200,192,6,208,246,32,204,255,162
  93. 172 DATA1,32,198,255,76,100,3,32,228,255,32,228,255,32,163,3
  94. 174 DATA32,176,3,76,88,3,32,228,255,240,10,201,42,208,247,32
  95. 176 DATA176,3,76,100,3,32,228,255,32,228,255,32,228,255,32,176
  96. 178 DATA3,32,228,255,32,176,3,32,228,255,201,13,240,48,201,34
  97. 180 DATA208,245,160,0,32,228,255,201,34,234,240,40,32,163,3,32
  98. 182 DATA176,3,76,146,3,201,128,144,2,233,128,201,32,176,2,169
  99. 184 DATA63,96,164,254,145,252,200,132,254,192,24,240,1,96,32,204
  100. 186 DATA255,40,40,96,234,32,228,255,201,0,240,154,32,163,3,32
  101. 188 DATA176,3,76,195,3
  102.